La commande subst permet de créer un lecteur de substitution d’un chemin sur un lecteur.
Exemple :
Sur le lecteur D: vous avez le dossier moi qui se trouve dans famille\enfants et vous voulez y accéder directement comme si ce dossier moi avait son propre lecteur. Vous aurez alors un lecteur M: (par exemple) qui remplacera les dossiers d:\famille\enfants\moi .

Pour cela, vous pouvez lancer dans une fenêtre dos, la commande
subst NomduLecteur: NomduChemin  ce qui fera

subst M: D:\famille\enfants\moi

Bien sur, les dossiers famille enfants moi doivent exister.

Ou alors, vous pouvez vous créer et lancer un fichier Batch :

rem Met un nom a la fenetre
Title Creation d'un lecteur local

rem efface tout
echo off
Cls

echo Menu Creation ou Suppression de lecteurs subst
echo ----------------------------------------------
echo     1. Creation Lecteur Local
echo     2. Supression Lecteur cree par SUBST
echo     3. Sortir
echo.
choice /c 123 /n
if errorlevel 3 goto fin
if errorlevel 2 goto suppression
if errorlevel 1 goto creation

:creation
echo Creation d'un lecteur local pour 
echo l'acces directe a un dossier.
echo Exemple : r: sera l'acces directe a un dossier 
echo Exemple c:\toto\tata\dossierx 
echo Ce dossier doit bien sur exister.
echo ----------------------------------------------

rem Etiquette debut
:debut
rem message a l'ecran
echo entrer une lettre de lecteur non utilisee :
rem entrer une donnee au clavier
rem recuperee par la variable lecteur local
set /p lecteur=
rem verification existance du lecteur local
rem si lecteur existe renvoi vers l'etiquette
if exist %lecteur%: goto lecteurexiste
echo Entrer le chemin d'acces complet
echo pour la creation du lecteur local
set /p chemin=
echo verification du lecteur et du chemin choisi
echo lecteur : %lecteur%: chemin : %chemin%
rem si le chemin n'existe pas renvoi vers l'etiquette
if not exist "%chemin%" goto cheminnotexiste
rem si le chemin existe, on cree le lecteur local
subst %lecteur%: "%chemin%"
rem Lancement explorer dans le lecteur créé
start explorer.exe %lecteur%:

goto fin

:suppression
echo Lettre du lecteur a supprimer (ne taper que la lettre)
rem Affichage des lecteurs crees par SUBST
subst
rem choix de la lettre
set /p lecteur=
rem Suppression de la lettre
subst %lecteur%: /d
pause
goto fin

:lecteurexiste
echo La lettre de ce lecteur existe deja
echo choisissez une autre lettre
pause
goto debut


:cheminnotexiste
echo le chemin n'existe pas
pause
:fin

Copiez les lignes dans un fichier texte et sauvegardez le sous le nom Lecteur_local.bat par exemple. Ou

Téléchargez-le ICI